# Beads package - issue tracker for AI-supervised coding workflows
# Takes src as argument so it can be called from both overlay and flake packages
{ lib
, buildGoModule
, fetchurl
, go_1_25
, git
, pkg-config
, icu
, src
, version ? "unknown"
}:

let
  # beads' dolt deps require Go >= 1.25.6 (GOTOOLCHAIN=auto can't download in sandbox)
  go_1_25_6 = go_1_25.overrideAttrs (old: rec {
    version = "1.25.6";
    src = fetchurl {
      url = "https://go.dev/dl/go${version}.src.tar.gz";
      hash = "sha256-WMv3ceRNdt5vVtGeM7d9dFoeSJNAkih15GWFuXXCsFk=";
    };
  });
  buildGoModule_1_25_6 = buildGoModule.override { go = go_1_25_6; };
in
buildGoModule_1_25_6 {
  pname = "beads";
  inherit version src;
  subPackages = [ "cmd/bd" ];
  doCheck = false;
  vendorHash = "sha256-M+JCxrKgUxCczYzMc2czLZ/JhdVulo7dH2YLTPrJVSc=";
  nativeBuildInputs = [ git pkg-config ];
  buildInputs = [ icu ];
  meta = with lib; {
    description = "beads (bd) - An issue tracker designed for AI-supervised coding workflows";
    homepage = "https://github.com/steveyegge/beads";
    license = licenses.mit;
    mainProgram = "bd";
  };
}