John Ogle
bbcb13881f
Extract duplicated overlay and home-manager configuration code into two reusable factory functions: - mkBaseOverlay: Creates the base overlay with unstable pkgs, custom packages, and bitwarden-desktop compatibility. Accepts optional unstableOverlays parameter for darwin-specific customizations. - mkHomeManagerConfig: Creates home-manager configuration with shared settings (useGlobalPkgs, useUserPackages, doom-emacs module). Accepts sharedModules parameter for platform-specific modules like plasma-manager. This reduces code duplication across nixosModules, nixosModulesUnstable, and darwinModules, making the flake easier to maintain and extend. Implements bead: nixos-configs-ek5
298 lines
9.6 KiB
Nix
298 lines
9.6 KiB
Nix
{
|
|
description = "A very basic flake";
|
|
|
|
inputs = {
|
|
nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";
|
|
nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable";
|
|
nixos-wsl.url = "github:nix-community/NixOS-WSL/main";
|
|
|
|
nix-darwin = {
|
|
url = "github:nix-darwin/nix-darwin/nix-darwin-25.11";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
|
|
home-manager = {
|
|
url = "github:nix-community/home-manager/release-25.11";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
|
|
home-manager-unstable = {
|
|
url = "github:nix-community/home-manager/master";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
|
|
plasma-manager = {
|
|
url = "github:nix-community/plasma-manager";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
inputs.home-manager.follows = "home-manager";
|
|
};
|
|
|
|
plasma-manager-unstable = {
|
|
url = "github:nix-community/plasma-manager";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
inputs.home-manager.follows = "home-manager-unstable";
|
|
};
|
|
|
|
google-cookie-retrieval = {
|
|
url = "git+https://git.johnogle.info/johno/google-cookie-retrieval.git";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
|
|
jovian = {
|
|
url = "github:Jovian-Experiments/Jovian-NixOS";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
|
|
beads = {
|
|
url = "github:steveyegge/beads";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
|
|
nix-doom-emacs-unstraightened = {
|
|
url = "github:marienz/nix-doom-emacs-unstraightened";
|
|
# Don't follow nixpkgs to avoid rebuild issues with emacs-overlay
|
|
inputs.nixpkgs.follows = "";
|
|
};
|
|
};
|
|
|
|
outputs = { self, nixpkgs, nixpkgs-unstable, nixos-wsl, ... } @ inputs: let
|
|
# Shared overlay function to reduce duplication across module sets
|
|
# Parameters:
|
|
# unstableOverlays: Additional overlays to apply when importing nixpkgs-unstable
|
|
mkBaseOverlay = { unstableOverlays ? [] }: (final: prev: {
|
|
unstable = import nixpkgs-unstable {
|
|
system = prev.stdenv.hostPlatform.system;
|
|
config.allowUnfree = true;
|
|
overlays = unstableOverlays;
|
|
};
|
|
custom = prev.callPackage ./packages {};
|
|
# Compatibility: bitwarden renamed to bitwarden-desktop in unstable
|
|
bitwarden-desktop = prev.bitwarden-desktop or prev.bitwarden;
|
|
});
|
|
|
|
# Shared home-manager configuration factory
|
|
# Parameters:
|
|
# sharedModules: Additional modules to include in home-manager.sharedModules
|
|
mkHomeManagerConfig = { sharedModules ? [] }: {
|
|
home-manager.useGlobalPkgs = true;
|
|
home-manager.useUserPackages = true;
|
|
home-manager.sharedModules = sharedModules ++ [
|
|
inputs.nix-doom-emacs-unstraightened.homeModule
|
|
];
|
|
home-manager.extraSpecialArgs = {
|
|
globalInputs = inputs;
|
|
};
|
|
};
|
|
|
|
nixosModules = [
|
|
./roles
|
|
inputs.home-manager.nixosModules.home-manager
|
|
{
|
|
nixpkgs.overlays = [ (mkBaseOverlay {}) ];
|
|
}
|
|
(mkHomeManagerConfig {
|
|
sharedModules = [ inputs.plasma-manager.homeModules.plasma-manager ];
|
|
})
|
|
];
|
|
|
|
# Modules for unstable-based systems (like nix-deck)
|
|
nixosModulesUnstable = [
|
|
./roles
|
|
inputs.home-manager-unstable.nixosModules.home-manager
|
|
inputs.jovian.nixosModules.jovian
|
|
{
|
|
nixpkgs.overlays = [ (mkBaseOverlay {}) ];
|
|
}
|
|
(mkHomeManagerConfig {
|
|
sharedModules = [ inputs.plasma-manager-unstable.homeModules.plasma-manager ];
|
|
})
|
|
];
|
|
|
|
darwinModules = [
|
|
./roles/darwin.nix
|
|
inputs.home-manager.darwinModules.home-manager
|
|
{
|
|
nixpkgs.overlays = [
|
|
(mkBaseOverlay {
|
|
# Override claude-code in unstable to use our custom GCS-based build
|
|
# (needed for corporate networks that block npm registry)
|
|
unstableOverlays = [
|
|
(ufinal: uprev: {
|
|
claude-code = uprev.callPackage ./packages/claude-code {};
|
|
})
|
|
];
|
|
})
|
|
];
|
|
}
|
|
(mkHomeManagerConfig { sharedModules = []; })
|
|
];
|
|
|
|
in {
|
|
nixosConfigurations.nix-book = nixpkgs.lib.nixosSystem rec {
|
|
system = "x86_64-linux";
|
|
modules = nixosModules ++ [
|
|
./machines/nix-book/configuration.nix
|
|
{
|
|
home-manager.users.johno = {
|
|
imports = [ ./home/home-laptop-compact.nix ];
|
|
# Machine-specific overrides
|
|
home.roles.i3_sway.extraSwayConfig = {
|
|
output.eDP-1.scale = "1.75";
|
|
};
|
|
};
|
|
home-manager.extraSpecialArgs = { inherit system; };
|
|
}
|
|
];
|
|
};
|
|
|
|
nixosConfigurations.boxy = nixpkgs.lib.nixosSystem rec {
|
|
system = "x86_64-linux";
|
|
modules = nixosModules ++ [
|
|
./machines/boxy/configuration.nix
|
|
{
|
|
home-manager.users.johno = import ./home/home-media-center.nix;
|
|
home-manager.users.kodi = import ./home/home-kodi.nix;
|
|
home-manager.extraSpecialArgs = { inherit system; };
|
|
}
|
|
];
|
|
};
|
|
|
|
nixosConfigurations.wixos = nixpkgs.lib.nixosSystem rec {
|
|
system = "x86_64-linux";
|
|
modules = nixosModules ++ [
|
|
nixos-wsl.nixosModules.default
|
|
./machines/wixos/configuration.nix
|
|
inputs.home-manager.nixosModules.home-manager
|
|
{
|
|
home-manager.users.johno = import ./home/home-desktop.nix;
|
|
home-manager.extraSpecialArgs = { inherit system; };
|
|
}
|
|
];
|
|
};
|
|
|
|
nixosConfigurations.zix790prors = nixpkgs.lib.nixosSystem rec {
|
|
system = "x86_64-linux";
|
|
modules = nixosModules ++ [
|
|
./machines/zix790prors/configuration.nix
|
|
inputs.home-manager.nixosModules.home-manager
|
|
{
|
|
home-manager.users.johno = import ./home/home-desktop.nix;
|
|
home-manager.extraSpecialArgs = { inherit system; };
|
|
}
|
|
];
|
|
};
|
|
|
|
# Live USB ISO configuration
|
|
nixosConfigurations.live-usb = nixpkgs.lib.nixosSystem rec {
|
|
system = "x86_64-linux";
|
|
modules = nixosModules ++ [
|
|
./machines/live-usb/configuration.nix
|
|
{
|
|
home-manager.users.nixos = import ./home/home-live-usb.nix;
|
|
home-manager.extraSpecialArgs = { inherit system; };
|
|
}
|
|
];
|
|
};
|
|
|
|
# Steam Deck configuration (using unstable for better Jovian compatibility)
|
|
nixosConfigurations.nix-deck = nixpkgs-unstable.lib.nixosSystem rec {
|
|
system = "x86_64-linux";
|
|
modules = nixosModulesUnstable ++ [
|
|
./machines/nix-deck/configuration.nix
|
|
{
|
|
home-manager.users.johno = import ./home/home-desktop.nix;
|
|
home-manager.extraSpecialArgs = { inherit system; };
|
|
}
|
|
];
|
|
};
|
|
|
|
# ZFS/NFS server configuration
|
|
nixosConfigurations.john-endesktop = nixpkgs.lib.nixosSystem rec {
|
|
system = "x86_64-linux";
|
|
modules = nixosModules ++ [
|
|
./machines/john-endesktop/configuration.nix
|
|
inputs.home-manager.nixosModules.home-manager
|
|
{
|
|
home-manager.users.johno = import ./home/home-server.nix;
|
|
home-manager.extraSpecialArgs = { inherit system; };
|
|
}
|
|
];
|
|
};
|
|
|
|
# Darwin/macOS configurations
|
|
darwinConfigurations."blkfv4yf49kt7" = inputs.nix-darwin.lib.darwinSystem rec {
|
|
system = "aarch64-darwin";
|
|
modules = darwinModules ++ [
|
|
./machines/johno-macbookpro/configuration.nix
|
|
{
|
|
home-manager.users.johno = import ./home/home-darwin-work.nix;
|
|
home-manager.extraSpecialArgs = { inherit system; };
|
|
}
|
|
];
|
|
};
|
|
|
|
# Flake apps
|
|
apps = nixpkgs.lib.genAttrs [ "x86_64-linux" "aarch64-linux" "aarch64-darwin" ] (system:
|
|
let
|
|
pkgs = import nixpkgs { inherit system; };
|
|
commonDeps = [ pkgs.curl pkgs.jq pkgs.nix pkgs.git pkgs.gnused pkgs.gnugrep pkgs.coreutils pkgs.gawk ];
|
|
|
|
update-doomemacs = pkgs.writeShellScriptBin "update-doomemacs" ''
|
|
export PATH="${pkgs.lib.makeBinPath commonDeps}:$PATH"
|
|
${builtins.readFile ./scripts/update-doomemacs.sh}
|
|
'';
|
|
|
|
update-claude-code = pkgs.writeShellScriptBin "update-claude-code" ''
|
|
export PATH="${pkgs.lib.makeBinPath commonDeps}:$PATH"
|
|
${builtins.readFile ./packages/claude-code/update.sh}
|
|
'';
|
|
|
|
rotate-wallpaper = pkgs.writeShellScriptBin "rotate-wallpaper" ''
|
|
export PATH="${pkgs.lib.makeBinPath commonDeps}:$PATH"
|
|
${builtins.readFile ./scripts/rotate-wallpaper.sh}
|
|
'';
|
|
|
|
upgrade = pkgs.writeShellScriptBin "upgrade" ''
|
|
export PATH="${pkgs.lib.makeBinPath commonDeps}:$PATH"
|
|
${builtins.readFile ./scripts/upgrade.sh}
|
|
'';
|
|
|
|
bootstrap = pkgs.writeShellScriptBin "bootstrap" ''
|
|
export PATH="${pkgs.lib.makeBinPath commonDeps}:$PATH"
|
|
${builtins.readFile ./scripts/bootstrap.sh}
|
|
'';
|
|
|
|
build-liveusb = pkgs.writeShellScriptBin "build-liveusb" ''
|
|
export PATH="${pkgs.lib.makeBinPath commonDeps}:$PATH"
|
|
${builtins.readFile ./scripts/build-liveusb.sh}
|
|
'';
|
|
in {
|
|
update-doomemacs = {
|
|
type = "app";
|
|
program = "${update-doomemacs}/bin/update-doomemacs";
|
|
};
|
|
update-claude-code = {
|
|
type = "app";
|
|
program = "${update-claude-code}/bin/update-claude-code";
|
|
};
|
|
rotate-wallpaper = {
|
|
type = "app";
|
|
program = "${rotate-wallpaper}/bin/rotate-wallpaper";
|
|
};
|
|
upgrade = {
|
|
type = "app";
|
|
program = "${upgrade}/bin/upgrade";
|
|
};
|
|
bootstrap = {
|
|
type = "app";
|
|
program = "${bootstrap}/bin/bootstrap";
|
|
};
|
|
build-liveusb = {
|
|
type = "app";
|
|
program = "${build-liveusb}/bin/build-liveusb";
|
|
};
|
|
}
|
|
);
|
|
};
|
|
}
|